Динамическая подсветка монитора на Arduino

Введение

Если вы любите смотреть фильмы на компьютере в темноте или играть в игры, то можно расширить возможности вашего монитора. Динамическая подсветка визуально расширяет границы экрана и благодаря ей ваши глаза будут меньше уставать. Этот проект очень прост и так как я сам новичок в общении с Arduino, могу посоветовать начинать создавать что-то для дома именно с этого проекта.

Итак, нам понадобится:

• Любая Arduino (UNO, Nano не важно).
• От 1-го до 2-х метров светодиодной ленты WS2812B, о которой вы можете почитать здесь, можно заказать на Aliexpress. Советую брать 60 светодиодов на метр для более качественно эффекта, но и 30 сойдет.
• Двусторонняя липкая лента или какой-нибудь клей.
• Источник питания 5В 2А (зарядник от планшета, например).
• Резистор на 220 Ом.
• Паяльные инструменты.
• Необходимое ПО для компьютера, а именно: Arduino IDE , AmbiBox, библиотека для Arduino IDE - FastLed.

Приступим.

Подключение

На светодиодной ленте есть три контакта - Плюс (+), Земля (G, GND) и вход (IN), а так же есть стрелочки, указывающее направление сигнала по ленте. Наша задача отрезать 4 отрезка светодиодной ленты таким образом. чтобы верхняя полоска была равна нижней, правая - левой. Отмерять будем прикладывая ленту с задней части нашего монитора. В общем нужно сделать так, как на картинке ниже.

Важно, чтоб количество светодиодов сверху и снизу было одинаковым, то же касается правой и левой стороны. Так же нужно учесть направление стрелок на самой ленте и припаять по порядку, как на картинке.
Теперь нам нужно подключить ленту к Arduino согласно схеме:

Минус от питания идет к контакту G на ленте и контакту GND на самой Arduino, Плюс напрямую к контакту (+) на ленте, а управляющий провод через резистор от ленты к нужному порту. Главное запомнить порт.

Собственно, подключение на этом закончили.

Настройка

Открываем установленную Arduino IDE и устанавливаем библиотеку FastLed (В верхнем меню выбрать "Скетч" - "Подключить библиотеку" - "Добавить ZIP библиотеку" и выбрать скачанный архив с библиотекой).

Теперь с помощью Arduino IDE заливаем в Arduino скетч:

#include "FastLED.h"

#define NUM_LEDS 44 // Количество светодиодов.
#define PIN 6 // Порт, к которому присоединен управляющий провод.
#define serialRate 115200

// Adalight отправляет «Магическое слово» (префик) перед отправкой данных.
uint8_t prefix[] = {'A', 'd', 'a'}, hi, lo, chk, i;

// Инициализация ленты.
CRGB leds[NUM_LEDS];

void setup()
{
  FastLED.addLeds(leds, NUM_LEDS);
  // Тест светодиодов.
  LEDS.showColor(CRGB(255, 0, 0));
  delay(500);
  LEDS.showColor(CRGB(0, 255, 0));
  delay(500);
  LEDS.showColor(CRGB(0, 0, 255));
  delay(500);
  LEDS.showColor(CRGB(0, 0, 0));
  Serial.begin(serialRate);
  Serial.print("Ada\n"); // Отправляем «магическое слово» для соединения с программой.
}

void loop()
{
  // Ждем первый байт из магического слова.
  for(i = 0; i < sizeof prefix; ++i)
  {
    waitLoop: while (!Serial.available());
    // Проверка следующего байта из магического слова.
    if(prefix[i] == Serial.read()) continue;
    // В противном случае начинаем все с начала.
    i = 0;
    goto waitLoop;
  }
  // Ждем старший и младший байт, а так же контрольную сумму.
  while (!Serial.available());
  hi = Serial.read();
  while (!Serial.available());
  lo = Serial.read();
  while (!Serial.available());
  chk = Serial.read();
  // Если контрольная сумма не совпала, начинаем все с начала.
  if (chk != (hi ^ lo ^ 0x55))
  {
    i = 0;
    goto waitLoop;
  }
  memset(leds, 0, NUM_LEDS * sizeof(struct CRGB));
  // Получаем данные и настраиваем соответствующий светодиод.
  for (uint8_t i = 0; i < NUM_LEDS; i++)
  {
    byte r, g, b;
    while(!Serial.available());
    r = Serial.read();
    while(!Serial.available());
    g = Serial.read();
    while(!Serial.available());
    b = Serial.read();
    leds[i].r = r;
    leds[i].g = g;
    leds[i].b = b;
  }
  // Отобразить новое состояние ленты.
  FastLED.show();
}

Перед заливкой нужно указать количество светодиодов, которое у вас получилось в сумме и порт, к которому вы припаяли управляющий провод.
У меня получилось 44 светодиода и использовался 6-й порт.
Если у вас лента и Arduino уже подключена к питанию, то после заливки скетча лента должна моргнуть тремя цветами, если этого не произошло, то отсоедините USB кабель и вставьте снова.

Теперь нам нужно установить программу AmbiBox.
При установке программа спросит, какое устройство будет использоваться, нам нужно указать Adalight.
В ней нам нужно перейти во вкладку "Интеллектуальная подсветка монитора".

Затем нажать "Больше настроек", теперь отображаются все функции.

Нам нужно указать порт, к которому подключена Arduino (цифра 1 на картинке).
Нужно указать количество светодиодов, которое у нас получилось (цифра 2 на картинке).
Выбрать метод захвата экрана. Тут на ваше усмотрение, поэкспериментируйте и выберите подходящее. У меня метод Windows 8 (цифра 3 на картинке).
Так же можно нажать "Показать зоны захвата" (цифра 4) и настроить их так, как наклеена лента. Ну. например, если у вас углы остались без светодиодов, то зоны можно сместить.
Не забудьте во вкладке "настройки программы" включить автозапуск с Windows.
На этом все. Все уже должно работать.

Тема на форуме.

Видео

Смотрите также

• Подключение адресной светодиодной ленты WS2812B к Arduino
• Подключение RGB светодиодной ленты к Arduino (LED 3528)
• Инъекция света